云电脑开关机通知至钉钉机器人

适用于 windows

测试环境为天翼云电脑 Windows Server 2016

消息预览

脚本内容

@echo off
setlocal

rem 定义请求地址
set "url=填写钉钉机器人 Webhook 地址"

rem 获取当前时间并格式化为字符串
set "currentDateTime=%date:~0,4%/%date:~5,2%/%date:~8,2% %time:~0,2%:%time:~3,2%:%time:~6,2%"

rem 获取地区信息
for /f "delims=" %%A in ('powershell -Command "(Invoke-RestMethod -Uri 'https://qifu-api.baidubce.com/ip/local/geo/v1/district?').data | ForEach-Object { $_.prov + ' ' + $_.city }"') do set "region=%%A"

rem 判断是否有参数
if "%~1"=="" (
    set "message=该设备即将关机或已开机"
) else (
    set "message=%~1"
)

rem 创建消息内容字符串
set "content=CurrenTime: %currentDateTime%\nRegion: %region%\nMessage: %message%"

rem 构建消息体
set "body={\"msgtype\":\"text\",\"text\":{\"content\":\"%content%\"}}"

rem 发送 HTTP POST 请求
powershell -Command "(Invoke-WebRequest -Uri '%url%' -Method Post -Body '%body%' -ContentType 'application/json;charset=utf-8')"

endlocal

创建钉钉机器人

群设置 - 机器人 - 添加机器人 - 自定义 - 添加

机器人名字：自定义

安全设置：自定义关键词

输入关键词：Message

勾选我已阅读并同意《自定义机器人服务及免责条款》，点击完成

复制 Webhook 地址填入脚本提示处，例如

rem 定义请求地址
set "url=https://oapi.dingtalk.com/robot/send?access_token=xxxxxxxxxxxxxxxxxxxxxxx"

配置云电脑

将脚本保存为英文名称 +.bat，例如 Event_Push.bat ，或者下载附件（文章最后）脚本

将脚本文件放置到路径

• C:\Windows\System32\GroupPolicy\Machine\Scripts\Startup
• C:\Windows\System32\GroupPolicy\Machine\Scripts\Shutdown

两个路径都放同样的脚本文件即可，放在一个路径也可以，放两个路径好找

组合按键 win+r，输入 gpedit.msc 回车打开本地组策略编辑器；或者搜索 编辑组策略 打开本地组策略编辑器

选择 计算机配置 - Windows 设置 - 脚本(启动/关机)，双击右侧 启动 按钮

点击 添加 - 浏览(B) - 选择放入的脚本文件，点击打开

脚本参数填入你想发送的开机提醒，例如 该设备已开机，点击确定，点击应用后再点击确定

双击 关机 按钮

点击 添加 - 浏览(B) - 选择放入的脚本文件，点击打开

脚本参数填入你想发送的开机提醒，例如 该设备即将关机，点击确定，点击应用后再点击确定

选择 计算机配置 - 管理模板 - 系统 - 组策略 - 配置登录脚本延迟

双击 配置登录脚本延迟，选择 已禁用，点击应用后再点击确定

此时已经完成全部配置，可以开关机电脑测试了~

EventPush.zip